Работа с регулярными выражениями в SQL Server

В SQL Server 7/2000 нет встроенной поддержки работы с регулярными выражениями. Но SQL Server похволяет работать с COM-объектами. В VBScript (библиотека vbscript.dll) есть специальный объект для работы с регулярными выражениями - RegExp.

Ниже приведен код хранимой процедуры sp_RegExpReplace, которая позволяет заменять текст, удовлетворяющий заданному регулярному выражению на другой заданный текст в строке.

Текст процедуры sp_RegExpReplace:

CREATE PROCEDURE [dbo].sp_RegExpReplace

@strIn1 varchar(8000),

@strIn2 varchar(8000),

@strPattern varchar(2000),

@strOut varchar(8000) OUT

AS

DECLARE @object int, @hr int

DECLARE @src varchar(255), @desc varchar(255)

-- создаем объект RegExp для работы с регулярными выражениями

EXEC @hr = sp_OACreate 'VBScript.RegExp', @object OUT

IF (@hr <> 0) BEGIN

EXEC sp_OAGetErrorInfo @object, @src OUT, @desc OUT

SELECT hr=convert(varbinary(4),@hr), Source=@src, Description=@desc

RETURN

END

EXEC @hr = sp_OASetProperty @object, 'Pattern', @strPattern

IF (@hr <> 0) BEGIN

EXEC sp_OAGetErrorInfo @object, @src OUT, @desc OUT

SELECT hr=convert(varbinary(4),@hr), Source=@src, Description=@desc

RETURN @hr

END

-- будет глобальная замена

EXEC @hr = sp_OASetProperty @object, 'Global', 1

IF (@hr <> 0) BEGIN

EXEC sp_OAGetErrorInfo @object, @src OUT, @desc OUT

SELECT hr=convert(varbinary(4),@hr), Source=@src, Description=@desc

RETURN @hr

END

-- вызов метода Replace

EXEC @hr = sp_OAMethod @object, 'Replace', @strOut OUT, @strIn1, @strIn2

IF (@hr <> 0) BEGIN

EXEC sp_OAGetErrorInfo @object, @src OUT, @desc OUT

SELECT hr=convert(varbinary(4),@hr), Source=@src, Description=@desc

RETURN @hr

END

-- удаляем объект

EXEC @hr = sp_OADestroy @object

IF (@hr <> 0) BEGIN

EXEC sp_OAGetErrorInfo @object, @src OUT, @desc OUT

SELECT hr=convert(varbinary(4),@hr), Source=@src, Description=@desc

RETURN @hr

END

RETURN 0

Необходимо учитывать, что пользователь, от имени которого будет запускаться наша процедура, должен входить в роль sysadmin (это ограничение накладывают процедуры sp_OACreate, sp_OASetProperty, sp_OAMethod, sp_OADestroy).

Протестируем процедуру sp_RegExpReplace - удалим с ее помощью из заданной строки все HTML-теги.

DECLARE @strOut varchar(8000)

EXEC sp_RegExpReplace 'Это тестовый <b>тест</b> <p> текст',

'', '<.+?>', @strOut OUT

SELECT @strOut

GO

В результате значением переменной @strOut будет строка "Это тестовый тест текст".

« Предыдущая статья		Следующая статья »